指標公式的編寫
1)、簡單的公式
例１ 十日均線指標（MA）
均線指標是求股票收市價的移動平均線，編寫公式的第一步，是到公式管理器提供的基本函數（即新建或修改公式中的“函數/公式”）中去查找需要的函數。
我們查到：函數CLOSE的功能是求當日收市價，函數MA(X,N)的功能是求X的N日移動平均線，所以10日均線指標的公式這樣寫： MA(CLOSE,10)。
您可以方便地在公式中引入加減乘除運算,請看下例。
例２ 乖離率指標（BIAS）
乖離率指標是求收市價與移動平均價的差,這個公式這樣寫： CLOSE - MA(CLOSE,10)。
上面兩個例子都是在一個圖上只繪一條指標線，如果您想在同一個圖上繪多條指標線，請看下例。
例３ 同圖繪制5日、10日、20日和60日均線
做起來非常簡單，您只需用分號將各指標公式隔開就行了。公式這樣寫：
MA(CLOSE,5);
MA(CLOSE,10);
條件選股公式的編寫
指標公式附加選股條件邏輯判斷表達式，就組成了條件選股公式。
條件選股就是將滿足條件的股票挑選出來，顯然條件選股公式中要用到邏輯操作符和邏輯函數，返回值為“１”（條件滿足）則選中該股，為“０”（條件不滿足）則不選中。與指標公式相比，條件選股公式可以有若干個中間公式，最后總是以一個邏輯式收尾。
例1，MACD指標中，MACD線由下向上穿越0線為買入信號，由上向下穿越0線為賣出信號，我們要挑出當天適合買入的股票,可將條件選股公式寫為:
參數名稱 最小值 最大值缺省值
LONG 20 100 26
SHORT 5 19 12
MID 2 20 9
DIFF:=EMA(CLOSE,SHORT) - EMA(CLOSE,LONG);
DEA:= EMA(DIFF,MID);
MACD:=DIFF-DEA;
CROSS(MACD,0)
例２，條件選股公式中可以直接引用指標公式。如上例MACD條件選股公式中的大部分內容與MACD指標公式是相同的，系統支持在條件選股公式中直接引用現成的指標公式，這樣可以大大地簡化公式書寫。但是這樣做可能會大幅降低系統處理速度。MACD條件選股公式又可以這樣寫:
參數名稱 最小值 最大值缺省值
LONG 20 100 26
SHORT 5 19 12
MID 2 20 9
CROSS("MACD.MACD"(LONG,SHORT,MID)，0)
"MACD.MACD"表示引用MACD指標公式中的MACD指標線，考察它是否上穿０線。在"MACD.MACD"后緊跟公式所帶的參數，參數名和參數個數都不能有錯。
引用指標的格式
引用指標的標準格式為：“指標公式名.指標線名”（參數表）
在實際應用中，可以有以下幾種變形：
* 如果指標名后不指定指標線，則系統自動引用該指標的最后一條指標線。MACD線恰好是MACD指標所繪指標線中的最后一條，因此可進一步簡寫為：
CROSS("MACD"(LONG,SHORT,MID),0)
* 如果將參數名都省去，寫成：CROSS("MACD"，０)，則參數值不再可變，固定取缺省值26、12、9。
* 如果寫成：CROSS("MACD"(30,10,6)，0)，則參數值固定為30、10、6。1
除條件選股公式外，交易系統公式也可以直接引用現成的指標公式。
如果對指標公式做了重要改動，例如增減了參數個數、修改了指標線名稱，系統會提示用戶對引用了該指標公式的條件選股公式、交易系統公式也作相應修改。否則相關聯的條件選股公式、交易系統公式的執行結果將不可預料。
例３ KD隨機指標中，K線向上穿越D線，且K線小于20為買入條件，因此KD條件選股公式這樣寫：
參數名稱 最小值 最大值缺省值
N1 1 40 9
N2 2 10 3
N3 2 10 3
RSV:=(CLOSE-LLV(LOW,N1))/(HHV(HIGH,N1)-
LLV(LOW,N1))*100；
K: =MA(RSV,N2)；
D: =MA(K,N3);
CROSS(K,D) AND K<20
例4，如果直接引用指標公式，KD條件選股公式可簡寫為：
參數名稱 最小值 最大值缺省值
N1 1 40 9
N2 2 10 3
N3 2 10 3
CROSS("KD.K"(N1,N1,N3),"KD.D"(N1,N2,N3)) AND
"KD.K"(N1,N2,N3)<20
例5，我們要挑出連跌三天的股票，條件選股公式這樣寫：
CLOSE<REF(CLOSE,1) AND
REF(CLOSE,1)<REF(CLOSE,2) AND
REF(CLOSE,2)<REF(CLOSE,3)
例6，若引入中間變量，上例也可以這樣寫：
DOWN:=REF(CLOSE,1)>CLOSE;
DOWN AND REF(DOWN,1) AND REF(DOWN,2)
交易系統公式編寫
指標公式稍加變形，再附加一些額外買賣條件表達式，就可作為交易系統公式。
交易系統公式用于交易系統指示、探索最佳參數和探索最佳指標，這就要求它能準確描述買入和賣出信號，對于期貨等還應能描述做空和做多信號。
和條件選股公式一樣，交易系統公式也必須包含邏輯式，用于指示買入、賣出信號。指示買入信號的公式在買入條件窗中輸入，指示賣出信號的公式在賣出條件窗中輸入，二者一定要成對出現。若您只需要一個信號，可將另一個信號設成恒為“不成立”，例如 0>1。交易系統公式所包含的中間公式在中間公式輸入窗中輸入。
在做交易系統指示功能時，交易系統公式的一組參數取缺省值。
在探索最佳參數時，交易系統公式的一組參數從最小值到最大值遍歷可能的組合，從中找出收益最大的一組參數值。收益采用中價計算，而且是考慮了手續費的。中價計算方法和手續費率可以在選項中設定。
在探索最佳指標時，系統針對某一只股票，測試到底哪一個交易系統公式最適合它，以及最佳收益如何。
在計算收益時，每次買入都假定使用全部資金買入，賣出時將全部股票賣出，收益率的計算是將每一次買賣的利潤進行連乘，當連續出現相同的信號時，僅考慮第一個信號。
在交易系統公式中，還可以輸入一些額外賣出條件，當這些條件之一滿足時，強制賣出。
下面舉例說明如何編寫交易系統公式。
例１ 以MACD指標為例，其交易系統公式這樣寫：
參數名稱 最小值 最大值缺省值 測試步長
LONG 20 100 26 5
SHORT 1 30 12 2
MID 5 20 9 2
中間公式：
DIFF:=EMA(CLOSE,SHORT) - EMA(CLOSE,LONG);
DEA:= EMA(DIFF,MID);
MACD:=DIFF-DEA;
多頭買入： CROSS(MACD,0)；
多頭賣出： CROSS(0,MACD)；
測試步長在探索最佳參數／指標時用到，這二者在實際計算過程中，都要遍歷參數組合。若步長為一，則遍歷所有可能組合；若步長不為一，則會跳過一些組合。前者得到的結果更精確，但遍歷范圍大，耗時長；后者結果稍粗略，但遍歷范圍小，節省時間。
買入條件為MACD由負變正；賣出條件反過來。
例２ 以KD指標為例，其交易系統公式這樣寫：
參數名稱 最小值 最大值缺省值 測試步長
N1 1 40 9 １
N2 2 10 3 １
N3 2 10 3 １
RSV:=(CLOSE-LLV(LOW,N1))/(HHV(HIGH,N1)-
LLV(LOW,N1))*100；
K: =MA(RSV,N2)；
D: =MA(K,N3);
多頭買入： CROSS(K,D) AND K<20
多頭賣出： CROSS(D,K) AND K>80
買入條件為K向上穿越D，并且K小于20。
賣出條件為D向上穿越K，并且K大于80。
交易系統公式中也可以直接引用現成的指標公式，這樣公式的書寫可以簡化。但可能會降低系統處理速度。
例３ MACD交易系統公式
參數名稱 最小值 最大值缺省值 測試步長
LONG 20 100 26 5
SHORT 1 30 12 2
MID 5 20 9 2
多頭買入： CROSS("MACD.MACD"(LONG,SHORT,MID),0)；
多頭賣出： CROSS(0, "MACD.MACD" (LONG,SHORT,MID))；
五彩K線公式編寫
五彩K線公式與條件選股公式相類似。
例1 當RSI小于20時顯示紅色，RSI大于80時顯示綠色。
"RSI.RSI1"<20,COLORRED;
"RSI.RSI1">80,COLORGREEN
公式中引用了RSI指標公式。
例2 早晨之星
早晨之星指示見底，后市看好。
早晨之星由三個交易日的Ｋ線組成：
第一日，在下跌市勢中，出現一支身體修長的陰燭。
第二日，跳空下跌，蠟燭線身體長度縮短，形成星的主體部分，它可以是陰燭，也可以是陽燭。
第三日，出現一支陽燭，回升到第一支燭線的范圍內。
我們用下面的公式來描述早晨之星：
REF(CLOSE,2)／REF(OPEN,2)＜0.95 AND
REF(OPEN,1)＜ REF(CLOSE,2) AND
ABS(REF(OPEN,1)-REF(CLOSE,1))／REF(CLOSE,1)＜0.03
AND CLOSE／OPEN ＞1.05 AND
CLOSE ＞REF(CLOSE,2)，COLORRED
第一個條件限制前天的K線為陰線，且收盤價與開盤價比較，跌幅在５％以上。
第二個條件限制昨天較前天跳空下跌。
第三個條件限制昨天開盤價與收盤價的差幅在３％以內。
第四個條件限制當天的Ｋ線為陽線，且收盤價與開盤價比較，升幅在５％以上。
第五個條件限制當天的收盤價高于前天的收盤價。
公式編寫的靈活性與特殊性
1)、可在每一公式后附加參數
分析系統可以在每一公式后附加一些外觀參數，以設置、區分各指標。附加的參數可以是：繪圖類型、繪圖顏色、線風格、線寬度之一或四者的任一組合。如下例：
MA5: MA(CLOSE,5),0,RGB(255,0,0),0,2；
MA10: MA(CLOSE,10),STICK,COLORGREEN,1,5；
MA20：MA(CLOSE,20)；
MA60：MA(CLOSE,60)
繪圖類型的取值：
繪圖類型可以取以下系統函數或2的n次冪（n>=0），建議使用系統函數。
STICK：柱狀線，從0到指標值間畫垂直線；
COLORSTICK：彩色柱狀線，當值為正時顯示紅色，否則顯示綠色；
VOLSTICK：成交量柱狀線，當股價上漲時顯示紅色空心柱，否則顯示綠色空心柱；
LINESTICK：同時畫出柱狀線和指標線；
CROSSDOT：小叉線；
CIRCLEDOT：小圓圈線；
POINTDOT：小圓點線。
（南方財富網www.zzyjzzsmh.com）
（責任編輯：張曉軒）