2. 提醒，有未來函數的公式不可怕，可怕的是買點賣點是由未來函數構成的，這種買點賣點的句子堅決不能要。
步驟一.將所有的顯示式":",改為不顯示式":="
選股條件的基本要求為只能輸出1個條件式,故要先將公式中所有的顯示式":"改為不顯示式":=",
如果原來顯示式后面接有線型描述(顏色.對齊..等),也一并刪除
例如:
ma1:ma(c,5),colorred;
ma2:ma(c,10),colorgreen,POINTDOT;
.....
先改為
ma1:=ma(c,5);
ma2:=ma(c,10);
.....
步驟二.找出選股條件,并寫成選股式引用:
條件的尋找方法,依不同目的,大致可分以下幾種:
--------------------------------------------------------------------------------------------
1.'字'選股 如:'買'選股
方法:先找出公式中出現有'字'的地方,該式開頭會以DRAW..TEXT開頭,
DRAWTEXT DRAWTEXTEX DRAWYITEXT DRAWFLAGTEXT DRAWMOVETEXT
找到后,該函數(條件, ,'字')后面括號內的第1個即為條件,將該條件復制出來并加上分號即可
例如:
{求'5日均>10日均'選股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWTEXT(ma1>ma2,ma1,'5日均>10日均');
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
--------------------------------------------------------------------------
2.圖標選股 如:笑臉選股
方法:
先依不同軟件,找出該圖標的代號,
再找出公式中出現DRAWICON函數(條件, ,圖標代號)的式子,對照圖標的代號(括號內的第3個),如果該圖標代號為所求代號,
該函數后面括號內的第1個即為條件,將該條件復制出來并加上分號即可
例如:
{求圖標1選股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
--------------------------------------------------------------------------------
3.A線上穿(下穿)B線選股 {上穿--金叉,下穿--死叉}
方法:A線上穿B線: cross(A,B);
A線下穿B線: cross(B,A);
例如:
{求ma1上穿ma2選股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1,ma2);
{求ma1下穿ma2選股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma2,ma1);
-------------------------------------------------------------------------------------------
4.線A上穿(下穿) 選股
方法:線A上穿: cross(A,ma(A,2)); 或 cross(A,ref(A,1));
線A下穿: cross(ma(A,2),A); 或 cross(ref(A,1),A);
例如:
{求改成ma1上穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma1,ma(ma1,2));
或
ma1:=ma(c,5);
cross(ma1,ref(ma1,1));
{求改成ma1下穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma(ma1,2),ma1);
或
ma1:=ma(c,5);
cross(ref(ma1,1),ma1);
---------------------------------------------------------------------------------------------
5.第1次出現條件A 選股
方法:先找出條件A,
再利用cross(A,0.5);
例如:
{求改成出現圖標1選股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解1]
ma1:=ma(c,5);
ma2:=ma(c,10);
A:=ma1>ma2;
cross(A,0.5);
[解2--直接將條件A寫入]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1>ma2,0.5);
-------------------------------------------------------------------------------------------
6.線變色選股 如:黃線變紅色選股 (指標線為黃線,再利用函數變紅色線)
方法:先依不同軟件,找出條件A,
再用cross(A,0.5);
(1)飛狐
條件在PARTLINE(條件A, ),colorred;括號內的第1個即為條件,將該條件復制出來并加上分號即可
例如:
{求黃線變紅色選股 飛狐}
ma1:ma(c,5),coloryellow;
PARTLINE(ma1>REF(ma1,1),ma1),colorred;
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);
(2)大智慧L2.分析家
條件在PARTLINE( ,條件A,rgb(255,0,0), , ...);
括號內為rgb(255,0,0)的前1個即為條件,將該條件復制出來并加上分號即可
例如:
{求黃線變紅色選股 大智慧L2.分析家}
ma1:=ma(c,5);
PARTLINE(ma1,ma1>REF(ma1,1),rgb(255,0,0),1,rgb(255,255,0));
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);
(3)通達信
條件在IF(條件A, ,DRAWNULL),colorred;括號內的第1個即為條件,將該條件復制出來并加上分號即可
例如:
{求黃線變紅色選股 通達信}
MA1:MA(C,5),COLORYELLOW;
IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED;
[解]
MA1:=MA(C,5);
A:=MA1>REF(MA1,1);
CROSS(MA1>REF(MA1,1),0.5);
--------------------------------------------------------------------------------
7.顏色柱選股
方法:先找出公式中出現有STICKLINE函數的地方,
找到后,核對該函數后面的顏色,是否為所求顏色,
若顏色相同,則括號內的第1個即為條件A,將該條件復制出來并加上分號即可
例如:
{求紅色柱選股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:c>o;
{求第1次紅色柱選股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:=c>o;
cross(A,0.5);
步驟三.最后將所有繪圖函數及單一輸出值(如 0; k; if(,,); )全刪除,使公式只剩1個選股式輸出即成,
(若有2個以上條件,條件同時成立時,可在條件間用"and"連接;
若有2個以上條件,允許條件不同時成立時,可在條件間用"or"連接)；（南方財富網www.zzyjzzsmh.com）
（責任編輯：張曉軒）